Dave Jarvis' Repositories

apply plugin: "java"
apply plugin: "application"

mainClassName = "to.discuss.Main"

sourceCompatibility = 1.8
targetCompatibility = 1.8

sourceSets {
  main {
    output.classesDir = "$buildDir/classes"

    java {
      srcDir "source/java"
    }

    // Ensure the logger properties file can be found
    resources {
      srcDirs = ['resources']
    }
  }
}

task copyLibraries( type: Copy ) {
  from configurations.runtime
  into "$buildDir/libs"
}

// Map menu items to servlets
task createServletMap( type: JavaExec ) {
  main = "net.sf.saxon.Transform"
  classpath = configurations.runtime
  args "-s:resources/menu/menu.xml", "-xsl:source/xsl/servlet/servlet.xsl"
}

createServletMap.dependsOn( copyLibraries )
run.dependsOn( [createServletMap] )

dependencies {
  // Authentication and authorization
  compile "org.apache.shiro:shiro-core:1.2.3"
  compile "org.apache.shiro:shiro-web:1.2.3"

  // XSLT 2.0 with EXSLT (http://exslt.org/) for XSLT math (e.g., fn:abs)
  compile "net.sourceforge.saxon:saxon:9.1.0.8"

  // Xerces XML parser; see resources/system.properties for usage
  compile "xerces:xercesImpl:2.11.0"

  // Database
  compile "org.postgresql:postgresql:9.3-1102-jdbc41"

  // Web Server
  compile "org.eclipse.jetty:jetty-server:9.2.6.v20141205"
  compile "org.eclipse.jetty:jetty-xml:9.2.6.v20141205"
  compile "org.eclipse.jetty:jetty-servlet:9.2.6.v20141205"
  compile "org.eclipse.jetty:jetty-webapp:9.2.6.v20141205"

  // Logging
  compile "org.slf4j:slf4j-log4j12:1.7.9"
  compile "commons-logging:commons-logging:1.2"
}

repositories {
  maven {
    url "https://maven.atlassian.com/repository/public/"
  }

  flatDir {
    dirs "lib"
  }
}